Scenario 4: Genetic Analysis on AML

Scenario 4: Genetic Analysis on AML#

Cell Line Derived from a Patient with AML#

A researcher is interested in the diversity and prevalence of genetic aberrations that cause AML in patients. A cell line has been derived from a patient with acute myeloid leukemia (AML). In order to acquire data that can be used for genetic analysis on this cell line, whole transcriptome RNA sequencing was performed of which the results have been used as input of the HAMLET pipeline. The HAMLET pipeline allows the simultaneous detection of genetic mutations. The result of the genetic test is stored in a phenopacket, which allows both genetic and phenotypic information to be stored as well as interoperability with other phenopacket data instances when queried.

Research Questions#

Question 1: Gene Mutation Prevalence#

Have patients been observed with variants in the same gene and the same diagnosis?

To answer this question the genes are found in which at least one mutation is present given the phenopacket of the AML cell line identified as new-reference-files and given a set of other instances of phenopackets collected from a public data source. This database contains phenopackets holding information from different published cases and cohort reports. The next step is to acquire the diagnosed diseases with which the relevant mutations are associated in the collected phenopackets. These steps are performed in the following SPARQL query:

PREFIX ex: <https://example.org/>
PREFIX obo: <http://purl.obolibrary.org/obo/>
PREFIX sio: <http://semanticscience.org/resource/>
PREFIX dcterms: <http://purl.org/dc/terms/> 
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT ?genesymbolvalue ?otherdiagnosis ?otherdiseaseid ?otherdiseaselabel
WHERE {
    GRAPH <http://example.org/HAMLET_DATA> {
        # Find phenopacket of AML cell line given its ID ('new-reference-files')
        ?phenopacket a obo:NCIT_C79269 ;
                    sio:SIO_000228 ?role .
        ?id sio:SIO_000020 ?role ;
            sio:SIO_000300 "new-reference-files" .
    
        # Find all genomic interpretations related to given phenopacket ID
        ?phenopacket sio:SIO_001403 ?interpr .
        ?interpr a obo:NCIT_C41255 ;
                sio:SIO_001403 ?diagnosis .
        ?diagnosis sio:SIO_001403 ?genomicinterpr .
        ?genomicinterpr a obo:SO_0001026 .
        
        # Find the genes that are relevant to the genomic interpretations
        ?genomicinterpr sio:SIO_001403 ?varinterpr .
        ?varinterpr a obo:SO_0001060 ;
                    sio:SIO_001403 ?vardescr .
        ?vardescr a obo:NCIT_C97927 ;
                sio:SIO_001403 ?genedescr .
        ?genedescr a obo:NCIT_C16612 ;
                dcterms:identifier ?geneid ;
                sio:SIO_000008 ?genesymbol .
        ?genesymbol sio:SIO_000300 ?genesymbolvalue .
    }
    GRAPH <http://example.org/MONARCH_PHENOPACKET_STORE_DATA> {
        # Find all diagnosed diseases where a mutation is found in same genes as given phenopacket
        ?othergenesymbol sio:SIO_000300 ?genesymbolvalue .
        ?othergenedescr sio:SIO_000008 ?othergenesymbol ;
                        dcterms:identifier ?othergeneid .
        ?othervardescr sio:SIO_001403 ?othergenedescr .
        ?othervarinterpr sio:SIO_001403 ?othervardescr .
        ?othergenomicinterp sio:SIO_001403 ?othervarinterpr .
        ?otherdiagnosis sio:SIO_001403 ?othergenomicinterp .
        ?otherdiagnosis sio:SIO_001403 ?otherdisease .
        ?otherdiseasevalue sio:SIO_000628 ?otherdisease ;
                        a obo:NCIT_C2991 .
        ?otherdisease dcterms:identifier ?otherdiseaseid ;
                    rdfs:label ?otherdiseaselabel ;
    }
    
    # Remove diagnosis of already given phenopacket
    FILTER (?diagnosis != ?otherdiagnosis)
}

From the collection of available phenopackets, a disease other than AML associated with a mutation in the same gene as for the given AML cell line is identified based on the query result shown below:

gene symbol diagnosis ID disease ID disease label
0 NRAS https://example.org/diagnosis_phenopacketbf2d0... OMIM:613224 Noonan syndrome 6
1 NRAS https://example.org/diagnosis_phenopacketb7df3... OMIM:613224 Noonan syndrome 6
2 NRAS https://example.org/diagnosis_phenopacket0aaf0... OMIM:613224 Noonan syndrome 6
3 NRAS https://example.org/diagnosis_phenopacket3b2b2... OMIM:613224 Noonan syndrome 6
4 NRAS https://example.org/diagnosis_phenopacket1caa9... OMIM:613224 Noonan syndrome 6
5 NRAS https://example.org/diagnosis_phenopacket0520c... OMIM:613224 Noonan syndrome 6
6 NRAS https://example.org/diagnosis_phenopacketf0c96... OMIM:613224 Noonan syndrome 6
7 NRAS https://example.org/diagnosis_phenopacketee17c... OMIM:613224 Noonan syndrome 6
8 NRAS https://example.org/diagnosis_phenopacketa127c... OMIM:613224 Noonan syndrome 6
9 NRAS https://example.org/diagnosis_phenopacket14db1... OMIM:613224 Noonan syndrome 6
10 NRAS https://example.org/diagnosis_phenopacketfa9d7... OMIM:613224 Noonan syndrome 6
11 NRAS https://example.org/diagnosis_phenopacketba7f5... OMIM:613224 Noonan syndrome 6
12 NRAS https://example.org/diagnosis_phenopacketc9101... OMIM:613224 Noonan syndrome 6
13 NRAS https://example.org/diagnosis_phenopacketfba27... OMIM:613224 Noonan syndrome 6

Conclusion#

Given the observations, patients have been found with variants in the same gene as in the AML cell line being the gene NRAS. However, these patients are diagnosed with a different disease, Noonan syndrome 6.

Contents